ARDUINO UNO WIFI REV2



Arduino UNO WiFi Rev.2 es el punto de entrada más fácil al IoT básico con el factor de forma estándar de la familia UNO. Ya sea que esté buscando construir una red de sensores conectada a su oficina o enrutador doméstico, o si desea crear un dispositivo BLE que envíe datos a un teléfono celular, Arduino UNO WiFi Rev.2 es su solución integral para muchos de los Escenarios básicos de aplicación de IoT.

Agregue esta placa a un dispositivo y podrá conectarla a una red WiFi, utilizando su acelerador de chip criptográfico ECC608 seguro. El Arduino Uno WiFi es funcionalmente igual que el Arduino Uno Rev3, pero con la adición de WiFi / Bluetooth y algunas otras mejoras. Incorpora el nuevo microcontrolador ATmega4809 de 8 bits de Microchip y tiene una IMU (Unidad de medición inercial) LSM6DS3TR incorporada.

El módulo Wi-Fi es un SoC autónomo con una pila de protocolos TCP / IP integrada que puede proporcionar acceso a una red Wi-Fi o actuar como un punto de acceso. Es el u-blox NINA-W102 .

Contiene todo lo necesario para soportar el microcontrolador. Simplemente conéctelo a una computadora con un cable USB o enciéndalo con un adaptador de CA o batería para comenzar.

Esta placa tiene el microcontrolador Microchip ATmega4809, pero gracias a la capa de compatibilidad incluida en el núcleo, puede ejecutar todos los bocetos realizados para el microcontrolador ATmega328P de UNO en el ATmega4809.

El chipset de comunicaciones del Arduino UNO WiFi Rev.2 puede ser un cliente y un dispositivo host BLE y Bluetooth®. Algo bastante único en el mundo de las plataformas de microcontroladores. 

ESPECIFICACIONES TECNICAS

  • Microcontrolador: Atmega4809
  • Tension de funcionamiento: 5v
  • Voltaje recomndado de entrada: 7-12v
  • Pines de E/S digitales: 14 (5 salida PWM)
  • Pines de entada analogica : 6
  • Corriente cc por pin de E/S : 20mA
  • corriente cc para pin de 3.3 v : 50mA
  • Memora Flash : 48 Kb
  • SRAM : 6.144Kb
  • EPROM : 256 Kb
  • Velocidad de reloj 16 Mhz
  • Modulo de radio : u-blox NINA-W102
  • Elemento seguro : ATECC608A
  • Unidad de medida inercial : LSM6DS3TR
  • LED_Builtin : 25
  • Dimensiones : 68.6 x 53.3 mm
  • Peso : 25 gr

DIMENSIONES

DOCUMENTACION

Descargar ide arduino
Guia de Referencia

DONDE COMPRAR

EJEMPLO DE CODIGO

/*

This example creates a client object that connects and transfers

data using always SSL.

It is compatible with the methods normally related to plain

connections, like client.connect(host, port).

Written by Arturo Guadalupi

last revision November 2015

*/

#include <SPI.h>
#include <WiFiNINA.h>

#include "arduino_secrets.h"
///////please enter your sensitive data in the Secret tab/arduino_secrets.h
char ssid[] = SECRET_SSID;        // your network SSID (name)
char pass[] = SECRET_PASS;    // your network password (use for WPA, or use as key for WEP)
int keyIndex = 0;            // your network key Index number (needed only for WEP)

int status = WL_IDLE_STATUS;
// if you don't want to use DNS (and reduce your sketch size)
// use the numeric IP instead of the name for the server:
//IPAddress server(74,125,232,128);  // numeric IP for Google (no DNS)
char server[] = "www.google.com";    // name address for Google (using DNS)

// Initialize the Ethernet client library
// with the IP address and port of the server
// that you want to connect to (port 80 is default for HTTP):

WiFiSSLClient client;

void setup() {

  //Initialize serial and wait for port to open:

  Serial.begin(9600);

  while (!Serial) {

    ; // wait for serial port to connect. Needed for native USB port only

  }

  // check for the WiFi module:

  if (WiFi.status() == WL_NO_MODULE) {

    Serial.println("Communication with WiFi module failed!");

    // don't continue

    while (true);

  }

  String fv = WiFi.firmwareVersion();

  if (fv < WIFI_FIRMWARE_LATEST_VERSION) {

    Serial.println("Please upgrade the firmware");

  }

  // attempt to connect to WiFi network:

  while (status != WL_CONNECTED) {

    Serial.print("Attempting to connect to SSID: ");

    Serial.println(ssid);

    // Connect to WPA/WPA2 network. Change this line if using open or WEP network:

    status = WiFi.begin(ssid, pass);

    // wait 10 seconds for connection:

    delay(10000);

  }

  Serial.println("Connected to wifi");

  printWiFiStatus();

  Serial.println("\nStarting connection to server...");

  // if you get a connection, report back via serial:

  if (client.connect(server, 443)) {

    Serial.println("connected to server");

    // Make a HTTP request:

    client.println("GET /search?q=arduino HTTP/1.1");

    client.println("Host: www.google.com");

    client.println("Connection: close");

    client.println();

  }
}

void loop() {

  // if there are incoming bytes available

  // from the server, read them and print them:

  while (client.available()) {

    char c = client.read();

    Serial.write(c);

  }

  // if the server's disconnected, stop the client:

  if (!client.connected()) {

    Serial.println();

    Serial.println("disconnecting from server.");

    client.stop();

    // do nothing forevermore:

    while (true);

  }
}

void printWiFiStatus() {

  // print the SSID of the network you're attached to:

  Serial.print("SSID: ");

  Serial.println(WiFi.SSID());

  // print your board's IP address:

  IPAddress ip = WiFi.localIP();

  Serial.print("IP Address: ");

  Serial.println(ip);

  // print the received signal strength:

  long rssi = WiFi.RSSI();

  Serial.print("signal strength (RSSI):");

  Serial.print(rssi);

  Serial.println(" dBm");
}